Micro Sizzle
by Jacob Joaquin
http://jacobjoaquin.tumblr.com


<CsoundSynthesizer>
<CsInstruments>
sr     = 44100
kr     = 4410
ksmps  = 10
nchnls = 1

/*
 * Analyze soundfile and print formatted data to Csound console.
 *
 * To capture output to console, use the following command-line in BASH:
 *     csound -g getSizzleData.csd 2> sizzleData.txt
 */
instr 1
	ibin         =    p4     /* Bin to analyze */
	ifftsize     =    128
	iwtype       =    1
	icaptureRate =    0.01   /* Rate to capture analysis data */
	kblock       init 0      /* Block index */
	
	/* Read data from soundfile */
	a1, a2 soundin "bbr.wav"

	/* Create stereo fsig pair */
	fsig0 pvsanal a1, ifftsize, ifftsize / 4, ifftsize, iwtype
	fsig1 pvsanal a2, ifftsize, ifftsize / 4, ifftsize, iwtype

	/* Get amp and frequency information */
	kamp0, kfreq0 pvsbin fsig0, ibin
	kamp1, kfreq1 pvsbin fsig1, ibin

	/* Print formatted messages to Csound console */
	/* Format: [band (block index) amplitude frequency channel] */
	printks "[%d %d %f %f %d]\n", icaptureRate, ibin, kblock, kamp0, kfreq0, 0
	printks "[%d %d %f %f %d]\n", icaptureRate, ibin, kblock, kamp1, kfreq1, 1
	
	/* Tracks k-rate block index */ 
	kblock = kblock + 1
endin

</CsInstruments>
<CsScore>

i 1 0 60 1
i 1 0 .  2
i 1 0 .  3
i 1 0 .  4
i 1 0 .  5
i 1 0 .  6
i 1 0 .  7
i 1 0 .  8
i 1 0 .  9
i 1 0 .  10
i 1 0 .  11
i 1 0 .  12
i 1 0 .  13
i 1 0 .  14
i 1 0 .  15
i 1 0 .  16
e

</CsScore>
</CsoundSynthesizer>